From d4a970f6962dda28133290194832b726b566ddab Mon Sep 17 00:00:00 2001
From: David Robillard <d@drobilla.net>
Date: Thu, 7 Jul 2022 18:59:06 -0400
Subject: Switch to meson build system

---
 plugins/eg-metro.lv2/meson.build | 41 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)
 create mode 100644 plugins/eg-metro.lv2/meson.build

(limited to 'plugins/eg-metro.lv2/meson.build')

diff --git a/plugins/eg-metro.lv2/meson.build b/plugins/eg-metro.lv2/meson.build
new file mode 100644
index 0000000..f881eca
--- /dev/null
+++ b/plugins/eg-metro.lv2/meson.build
@@ -0,0 +1,41 @@
+# Copyright 2022 David Robillard <d@drobilla.net>
+# SPDX-License-Identifier: CC0-1.0 OR ISC
+
+plugin_sources = files('metro.c')
+bundle_name = 'eg-metro.lv2'
+data_filenames = ['manifest.ttl.in', 'metro.ttl']
+
+module = shared_library(
+  'metro',
+  plugin_sources,
+  c_args: c_suppressions,
+  dependencies: [lv2_dep, m_dep],
+  gnu_symbol_visibility: 'hidden',
+  install: true,
+  install_dir: lv2dir / bundle_name,
+  name_prefix: '',
+)
+
+config = configuration_data(
+  {
+    'LIB_EXT': '.' + module.full_path().split('.')[-1],
+  }
+)
+
+foreach filename : data_filenames
+  if filename.endswith('.in')
+    configure_file(
+      configuration: config,
+      input: files(filename),
+      install_dir: lv2dir / bundle_name,
+      output: filename.substring(0, -3),
+    )
+  else
+    configure_file(
+      copy: true,
+      input: files(filename),
+      install_dir: lv2dir / bundle_name,
+      output: filename,
+    )
+  endif
+endforeach
-- 
cgit v1.2.1